Category: SQL Server

by Fran Lens 2012-05-14

How to create an SQL Server 2012 installer with integrated CU1 (Product Updates – Slipstream)

Time ago, I created an automated batch procedure to create an SQL Server 2008 R2 Installer with Integrated SP1, known as Slipstream, now in SQL Server 2012 this was replaced with a new funcionality called Product Updates. 

With the Product Updates funcionality we can integrate Service Pack or Cumulative Updates to the SQL Server installer, this save much time, specially when you need to do multiple installations. 

This guide is based on Product Updates in SQL Server 2012 Installation, to which I add a .bat file to save time. 

This guide is for the English version of SQL Server 2012. Here are the steps: 

1. Copy all the installations files of SQL Server 2012 to C:\SQLServer2012 

2. Download Microsoft® SQL Server® 2012 Cummulate Update 1, you need to download x86 and x64 architectures and copy them to C:\

• SQLServer2012_RTM_CU1_kb2679368_11_0_2316_x86 (446573_intl_i386_zip.exe)
• SQLServer2012_RTM_CU1_kb2679368_11_0_2316_x64 (446572_intl_x64_zip.exe)

3. Create a .bat file with this content and copy it to C:\

@ECHO OFF

::File Verification
IF NOT EXIST "C:\SQLServer2012\" GOTO ERROR
IF NOT EXIST "C:\446573_intl_i386_zip.exe" GOTO ERROR
IF NOT EXIST "C:\446572_intl_x64_zip.exe" GOTO ERROR

::Extract each of the SQL Server 2012 CU1 packages to C:\SQLServer2012\Updates
ECHO Extracting SP files to C:\SQLServer2012\Updates...
start /wait C:\446573_intl_i386_zip.exe /x:C:\SQLServer2012\Updates
ECHO Extract of SQLServer2012_RTM_CU1_kb2679368_11_0_2316_x86 (446573_intl_i386_zip.exe) Completed
start /wait C:\446572_intl_x64_zip.exe /x:C:\SQLServer2012\Updates
ECHO Extract of SQLServer2012_RTM_CU1_kb2679368_11_0_2316_x64 (446572_intl_x64_zip.exe) Completed
ECHO.

::Create or modify DefaultSetup.ini
IF NOT EXIST "C:\SQLServer2012\x86\DefaultSetup.ini" GOTO CREATEINI
ECHO Modifying DefaultSetup.ini
TYPE C:\SQLServer2012\x86\DefaultSetup.ini > C:\SQLServer2012\x86\Temp_DefaultSetup.ini
ECHO UpdateEnabled=TRUE >> C:\SQLServer2012\x86\Temp_DefaultSetup.ini
ECHO UpdateSource=.\Updates >> C:\SQLServer2012\x86\Temp_DefaultSetup.ini
DEL C:\SQLServer2012\x86\DefaultSetup.ini
REN C:\SQLServer2012\x86\Temp_DefaultSetup.ini DefaultSetup.ini
ECHO.
GOTO COPYINI
:CREATEINI
ECHO Creating or modifying DefaultSetup.ini
ECHO ;SQL SERVER 2012 Configuration File > C:\SQLServer2012\x86\DefaultSetup.ini
ECHO [OPTIONS] >> C:\SQLServer2012\x86\DefaultSetup.ini
ECHO UpdateEnabled=TRUE >> C:\SQLServer2012\x86\DefaultSetup.ini
ECHO UpdateSource=.\Updates >> C:\SQLServer2012\x86\DefaultSetup.ini
ECHO.
:COPYINI

::Copy DefaultSetup.ini from x86 to x64 folder
ECHO Copying DefaultSetup.ini from x86 to x64 folder
start /wait robocopy C:\SQLServer2012\x86 C:\SQLServer2012\x64 DefaultSetup.ini
ECHO.

ECHO ==============================================================================
ECHO OPERATION COMPLETED
ECHO Use C:\SQLServer2012\Setup.exe to install SQL Server 2012 + CU1
ECHO ==============================================================================
ECHO.
GOTO FIN

:ERROR
ECHO ==============================================================================
ECHO FILE VERIFICATION FAIL, PLEASE CHECK THE FOLLOWING:
ECHO THE DIRECTORY C:\SQLServer2012\ EXISTS
ECHO 446573_intl_i386_zip.exe FILE IS LOCATED IN C:\
ECHO 446572_intl_x64_zip.exe FILE IS LOCATED IN C:\
ECHO ==============================================================================
ECHO.

:FIN

PAUSE

4. Run the .bat file as administrator. 

5. When ask for a folder to extract the files, type C:\SQLServer2012\Updates 

6. Use C:\SQLServer2012\Setup.exe to start the installation. 

7. You can check that the installation contains Product Updates in the Product Updates screen and the Ready to Install screen: